From 4fd0310818738d7acd0460d16ec27e7daeae8b26 Mon Sep 17 00:00:00 2001
From: nevaforget <dom@moonarch.de>
Date: Wed, 10 Jun 2026 18:58:19 +0200
Subject: [PATCH] feat: add corsairctl package (tag-build)

---
 corsairctl/.SRCINFO | 15 +++++++++++++++
 corsairctl/PKGBUILD | 33 +++++++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)
 create mode 100644 corsairctl/.SRCINFO
 create mode 100644 corsairctl/PKGBUILD

diff --git a/corsairctl/.SRCINFO b/corsairctl/.SRCINFO
new file mode 100644
index 0000000..f7b89f8
--- /dev/null
+++ b/corsairctl/.SRCINFO
@@ -0,0 +1,15 @@
+pkgbase = corsairctl
+	pkgdesc = CLI tool for Corsair Bragi-protocol devices (HS80 RGB Wireless, etc.)
+	pkgver = 0.1.2
+	pkgrel = 1
+	url = https://gitea.moonarch.de/nevaforget/corsairctl
+	arch = x86_64
+	license = MIT
+	makedepends = cargo
+	makedepends = pkg-config
+	depends = hidapi
+	depends = alsa-lib
+	source = git+https://gitea.moonarch.de/nevaforget/corsairctl.git#tag=v0.1.2
+	sha256sums = SKIP
+
+pkgname = corsairctl
diff --git a/corsairctl/PKGBUILD b/corsairctl/PKGBUILD
new file mode 100644
index 0000000..67809c1
--- /dev/null
+++ b/corsairctl/PKGBUILD
@@ -0,0 +1,33 @@
+# Maintainer: nevaforget <dom@moonarch.de>
+pkgname=corsairctl
+pkgver=0.1.2
+pkgrel=1
+pkgdesc='CLI tool for Corsair Bragi-protocol devices (HS80 RGB Wireless, etc.)'
+arch=('x86_64')
+url='https://gitea.moonarch.de/nevaforget/corsairctl'
+license=('MIT')
+depends=('hidapi' 'alsa-lib')
+makedepends=('cargo' 'pkg-config')
+source=("git+${url}.git#tag=v$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+    cd "$pkgname"
+    export RUSTUP_TOOLCHAIN=stable
+    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+    cd "$pkgname"
+    export RUSTUP_TOOLCHAIN=stable
+    export CARGO_TARGET_DIR=target
+    cargo build --frozen --release
+}
+
+package() {
+    cd "$pkgname"
+    install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
+    install -Dm755 "scripts/corsairctl-waybar.sh" "$pkgdir/usr/bin/corsairctl-waybar"
+    install -Dm644 "udev/99-corsair.rules" "$pkgdir/usr/lib/udev/rules.d/99-corsair.rules"
+    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}